Multicollinearity: testMC1.tol

#Require MMS;

Real PutRandomSeed(2143);
Serie s1 = SubSer(Gaussian(0, 1, C), y2001, y2002);
Serie s2 = SubSer(Gaussian(0, 1, C), y2001, y2002);

MMS::@DataSet dataSet = MMS::Container::ReplaceDataSet([[
  Text _.name = "DataSet.Ej1"
]]);

MMS::@Variable v1 = dataSet::CreateVariable([[
  Text _.name = "Variable1";
  Text _.type = "Serie";
  Text _.expression = "Serie Copy(s1);"
]]);

MMS::@Variable v2 = dataSet::CreateVariable([[
  Text _.name = "Variable2";
  Text _.type = "Serie";
  Text _.expression = "Serie Copy(s2);"
]]);

MMS::@Variable v3 = dataSet::CreateVariable([[
  Text _.name = "Variable3";
  Text _.type = "Serie";
  Text _.expression = "Serie %1 * 2"; // tipo1
  // Text _.expression = "Serie %1 * 0"; // tipo2
  Set _.dependences = [[ "Variable2" ]]
]]);

MMS::@Model model = MMS::Container::ReplaceModel([[
  Text _.name = "Model.Ej1";
  Set _.dataSets = [[ "DataSet.Ej1" ]]
]]);

MMS::@Submodel submodel = model::CreateSubmodel([[
  Text _.name = "Submodel";
  NameBlock _.output = [[
    Text _.name = "Output";
    Text _.variable = "Variable1"
  ]];
  NameBlock _.noise = [[
    Text _.type = "Normal"
  ]]
]]);

MMS::@ExpTerm expTerm1 = submodel::CreateExpTerm_TransferFunction([[
  Text _.name = "ExpTerm1";
  NameBlock _.input = [[
    Text _.name = "Input1";
    Text _.variable = "Variable2"
  ]];
  Polyn _.transferFunction = 0.1
]]);

MMS::@ExpTerm expTerm2 = submodel::CreateExpTerm_TransferFunction([[
  Text _.name = "ExpTerm2";
  NameBlock _.input = [[
    Text _.name = "Input2";
    Text _.variable = "Variable3"
  ]];
  Polyn _.transferFunction = 0.1
]]);

MMS::@Estimation estimation = MMS::Container::ReplaceEstimation([[
  Text _.name = "Estimation.Ej1";
  MMS::@Model _.model = model;
  MMS::@SettingsBSR _.settings = [[
    // Se usa un valor bajo de 'mcmc.sampleLength' para agilizar pruebas
    Real mcmc.sampleLength = 200;
    Real do.report = True // False
  ]]
]]);

//////////////////////////////////////////////////////////////////////////////
// Ejecución de la estimación: -> No es posible aplicar CholeskiFactor

// Real estimation::Execute(?);

//////////////////////////////////////////////////////////////////////////////

Set submodel::CheckMulticollinearity(?);
//> Colinealidad:
// (tipo1)
// "Submodel__ExpTerm1__Linear.0"
// "Submodel__ExpTerm2__Linear.0"
// (tipo2)
// "Submodel__ExpTerm2__Linear.0"

//////////////////////////////////////////////////////////////////////////////