Ticket #894: alternative.tol

//////////////////////////////////////////////////////////////////////////////
// Alternativas a las funciones sugeridas en el tique #894

// Partimos de la instancia del modelo: 'model'
MMS::@Model model = MMS::Container::GetForecast(1)::GetModel(?);

//////////////////////////////////////////////////////////////////////////////
// [FindProb]

Set FindProb(model);

// Para encontrar la lista de variables independientes que dan problemas
// podemos hacer lo siguiente:

// Tomar el conjunto de variables independientes:
Set variablesI = model::GetDataSet(?)::GetVariablesI(?);
 
// Encontrar las que dan error apoyándonos en una función de tipo más
// general habilitada al efecto:
Set Include("checkErrors.tol");
Set varsI_Prob = CheckErrors(variablesI, Anything (MMS::@Variable v) {
  v::GetData(?)
}, 1/50); // traza 1 de cada 50

// Para obtener la lista con sus identificadores (aunque si trabajamos
// directamente con las instancias no nos hará falta) basta con:
Set varsI_Prob_Ids = EvalSet(varsI_Prob, Text (MMS::@Variable variable) {
  variable::GetIdentifier(?)
}); 

//////////////////////////////////////////////////////////////////////////////
// [OffByName]
// [OffMiss]
// [OffFlat]
// [OffBeginEnd]

Set OffByName(varsI_Prob_Ids, model);
Set OffMiss(model);
Set OffFlat(model);
  Date begin = y2006;
  Date end = y2012;
Set OffBeginEnd(model, begin, end);

// Para desactivar un conjunto de términos explicativos (y por tanto sus
// parámetros) hemos de localizarlos siguiendo algún criterio.

// Para estos casos es especialmente útil disponer de un método que nos
// devuelva el conjunto de términos explicativos activos cuyo input
// responda a un determinado criterio.

// Nos apoyamos en una función auxiliar preparada al efecto:
Set Include("selectExpTermsActive_ByInputTest.tol");
// Set SelectExpTermsActive_ByInputTest(MMS::@Model model, Code inputTest) 

Set offByName = SelectExpTermsActive_ByInputTest(model, 
  Real (MMS::@MVariable input) {
  // Encontramos todas las dependencias independientes del input:
  Set depsI = input::GetVariable(?)::GetDependencesI(?);
  // Comprobamos si hay alguna que esté en el conjunto de variables
  // problemáticas:
  Card(MMS::Intersection_Eq(depsI, varsI_Prob, SameNameBlock))
});
// Desactivamos los términos anteriores:
Set EvalSet(offByName, Real (MMS::@ExpTerm expTerm) {
  expTerm::SetIsActive(False)
});

Set offMiss = SelectExpTermsActive_ByInputTest(model, 
  Real (MMS::@MVariable input) {
  // Comprobamos si el input presenta omitidos
  HasUnknown(input::GetData(?))
});
// Desactivamos los términos anteriores:
Set EvalSet(offMiss, Real (MMS::@ExpTerm expTerm) {
  expTerm::SetIsActive(False)
});

Set offFlat = SelectExpTermsActive_ByInputTest(model, 
  Real (MMS::@MVariable input) {
  // Comprobamos si el input es constante
  Serie data = input::GetData(?);
  MaxS(data) == MinS(data)
});
// Desactivamos los términos anteriores:
Set EvalSet(offFlat, Real (MMS::@ExpTerm expTerm) {
  expTerm::SetIsActive(False)
});

Set offBeginEnd = SelectExpTermsActive_ByInputTest(model, 
  Real (MMS::@MVariable input) {
  // Comprobamos si el input es constante
  Serie data = input::GetData(?);
  Date first = First(data);
  Date last = Last(data);
  (first > begin) | (last < end)
});
// Desactivamos los términos anteriores:
Set EvalSet(offBeginEnd, Real (MMS::@ExpTerm expTerm) {
  expTerm::SetIsActive(False)
});

//////////////////////////////////////////////////////////////////////////////
// [SelectDepend]

Set SelectDepend(varsI_Prob_Ids, model);

// Para seleccionar la lista de variables dependientes de un determinado 
// conjunto basta hacer:

Set varsI_Prob_Dependents = MMS::Unique_Eq(SetConcat(EvalSet(varsI_Prob, 
  Set (MMS::@Variable variable) {
  variable::GetDependents_ToLevel(?)
})), SameNameBlock);

// La lista total de problemáticas será:

Set vars_Prob = varsI_Prob << varsI_Prob_Dependents;

Set vars_Prob_Ids = EvalSet(varsI_Prob, Text (MMS::@Variable variable) {
  variable::GetIdentifier(?)
}); 

//////////////////////////////////////////////////////////////////////////////
// [RemoveByName]

Set RemoveByName(vars_Prob_Ids, model);

// Para borrar las variables basta con hacer:
Set EvalSet(vars_Prob, Real (MMS::@Variable variable) {
  variable::Delete(?)
});

//////////////////////////////////////////////////////////////////////////////