Ticket #690: test_forDespuesFinEst.tol

//////////////////////////////////////////////////////////////////////////////
// FILE    : 
// PURPOSE :
//////////////////////////////////////////////////////////////////////////////

MMS::Container::RemoveForecasts(?);
MMS::Container::RemoveEstimations(?);
MMS::Container::RemoveModels(?);
MMS::Container::RemoveDataSets(?);


Date DesdeEst = y2001m01d01;
Date HastaEst = y2002m01d01;

Date DesdeFor = Succ(HastaEst, Diario, 10);
Date HastaFor = Succ(HastaEst, Diario, 20);


Date Hasta = Max(HastaEst, HastaFor); // Para los inputs

//////////////////////////////////////////////////////////////////////////////
Serie CreateOutput(Real isMult, Date desde, Date hasta){
//////////////////////////////////////////////////////////////////////////////
  Serie media = {
    Set avrWD = If(isMult,
      [[1.1,  1.12, 1.15, 1.2, 1.3, 1.35, 1.5]],
      [[1000, 1100, 1300, 1600, 2100, 2600, 3000]]
    );

  
    Set byWD = For(1, Card(avrWD), Serie(Real k_wd){
      avrWD[k_wd] * CalInd(WD(k_wd))
    });
  
    SetSum(byWD)
  };
  
  Polyn ari = (1-B^7)*(1-0.4*B);
  Polyn ma  = (1-0.8*B^7);
  
  
  Serie residuos = If(isMult,
    SubSer(Gaussian(0, 0.05), desde, hasta),
    SubSer(Gaussian(0, 100), desde, hasta)
  );

  Serie noise = DifEq(ma/ari, residuos, media);
  
  Serie inputs = {
    Serie ser01 = If(isMult,
      0.13*CalInd(In(y2001m03d01, y2001m04d01)),
      1300*CalInd(In(y2001m03d01, y2001m04d01))
    );

    Serie ser02 = If(isMult,
      0.17*Pulse(y2001m07d01),
      1500*Pulse(y2001m07d01)
    );

    Serie ser03 = If(isMult,
      0.15*TendLocNegTimeSet(C, y2001m09d01, y2001m10d01),
      1400*TendLocNegTimeSet(C, y2001m09d01, y2001m10d01)
    );

    ser01 + ser02 + ser03
  }; 
  
  noise + inputs
};
//////////////////////////////////////////////////////////////////////////////


// Data Set Outputs
MMS::@DataSet DS_Out = MMS::Container::ReplaceDataSet([[
  Text _.name = "dsOut";
  Text _.description = "DataSet de outputs"
]]);

// Data Set Inputs
MMS::@DataSet DS_Inp = MMS::Container::ReplaceDataSet([[
  Text _.name = "dsInp";
  Text _.description = "DataSet de inputs"
]]);


Real DS_Out::AppendInterval("Diario", DesdeEst, HastaEst);
Real DS_Inp::AppendInterval("Diario", DesdeEst, HastaEst);


Real DS_Out::ReplaceVariable([[
  Text _.name = "OutputUnico";
  Text _.description = "output";
  Text _.expression = "CreateOutput(1, DesdeEst, HastaEst)";
  Text _.type = "Serie";
  Real _.isTrivial = 0;
  Set _.tags = [[ "Output", "Pulse" ]]
]]);


Real DS_Inp::ReplaceVariable([[
  Text _.name = "CalInd_y2001m03d01";
  Text _.description = "escalón";
  Text _.expression 
    = "SubSer(CalInd(In(y2001m03d01, y2001m04d01)), DesdeEst, Hasta)";
  Text _.type = "Serie";
  Real _.isTrivial = 0;
  Set _.tags = [[ "Input", "CalInd" ]]
]]);


Real DS_Inp::ReplaceVariable([[
  Text _.name = "Pulse_y2001m07d01";
  Text _.description = "pulso";
  Text _.expression 
    = "SubSer(Pulse(y2001m07d01), DesdeEst, Hasta)";
  Text _.type = "Serie";
  Real _.isTrivial = 0;
  Set _.tags = [[ "Input", "Pulse" ]]
]]);


Real DS_Inp::ReplaceVariable([[
  Text _.name = "Trend_y2001m09d01";
  Text _.description = "tendencia";
  Text _.expression 
    = "SubSer(TendLocNegTimeSet(C, y2001m09d01, y2001m10d01), DesdeEst, Hasta)";
  Text _.type = "Serie";
  Real _.isTrivial = 0;
  Set _.tags = [[ "Input", "Trend" ]]
]]);


MMS::@Model Modelo = MMS::Container::ReplaceModel([[
  Text _.name = "ModeloUnico";
  Text _.description = "modelo único";
  Text _.version = "1.0";
  Set _.dataSets = SetOfText("dsOut", "dsInp") 
]]);

MMS::@Submodel Submodelo = Modelo::CreateSubmodel([[
  Text _.name = "SubmodeloUnico";
  NameBlock _.output = [[ 
    Text _.name = "OutputUnico";
    Text _.variableIdentifier = "OutputUnico";
    MMS::@Transformation _.transformation 
      = MMS::@Transformation.BoxCox::Default(0,0)
  ]];
  Date _.begin = DesdeEst;
  Date _.end   = HastaEst;
  NameBlock _.noise = [[
  Text _.type = "ARIMA";
  Text _.arimaLabel = "P1_7DIF0_1AR1_0MA0_7";
  Real _.sigma = 1
  ]]
]]);

NameBlock Submodelo::CreateExpTerm_TransferFunction([[
  Text _.name = "Pulse_y2001m07d01";
  NameBlock _.input = [[
    Text _.name = "Pulse_y2001m07d01"; 
    Text _.variableIdentifier = "Pulse_y2001m07d01"
  ]];    
  Polyn _.transferFunction = 1
]]);

NameBlock Submodelo::CreateExpTerm_TransferFunction([[
  Text _.name = "CalInd_y2001m03d01";
  NameBlock _.input = [[
    Text _.name = "CalInd_y2001m03d01"; 
    Text _.variableIdentifier = "CalInd_y2001m03d01"
  ]];    
  Polyn _.transferFunction = 1
]]);


NameBlock Submodelo::CreateExpTerm_TransferFunction([[
  Text _.name = "Trend_y2001m09d01";
  NameBlock _.input = [[
    Text _.name = "Trend_y2001m09d01"; 
    Text _.variableIdentifier = "Trend_y2001m09d01"
  ]];    
  Polyn _.transferFunction = 1
]]);


MMS::@Estimation Estimacion = MMS::Container::ReplaceEstimation([[
  Text _.name = "EstimacionUnica";
  MMS::@Model _.model = Modelo;

  MMS::@SettingsMultiMLE _.settings = [[
    Real _.showTraces =  False
  ]]
]]);


Real Estimacion::Execute(?);

Set Parametros = Estimacion::GetParameters(?);


MMS::@Forecast Prevision = MMS::Container::ReplaceForecast([[
  Text _.name = "Forecast_caso00";
  MMS::@SettingsForecast _.settings = [[
    Text _.mode = "Point";
    Real _.showTraces = False
  ]];
  MMS::@Model _.model = Modelo; // Estimacion::GetModel(?);
  Set _.parameters = Parametros;
  // MMS::@Model _.estimation = Estimacion;
  Set _.fIntervals = {Set [[ 
     Set [["*", DesdeFor, HastaFor]] 
  ]] }
]]);


Real Prevision::Execute(?);