Ticket #487: functions.tol

//////////////////////////////////////////////////////////////////////////////
// File:    functions.tol
// Purpose: It defines functions to create useful general input variables: 
// summer, Easter, Christmas & festives
//////////////////////////////////////////////////////////////////////////////

//////////////////////////////////////////////////////////////////////////////
// Structures
//////////////////////////////////////////////////////////////////////////////

Struct InputDef(
  Polyn Omega,
  Serie X
);

//////////////////////////////////////////////////////////////////////////////
// Constants
//////////////////////////////////////////////////////////////////////////////

Set Standard.Variables = Empty;

//////////////////////////////////////////////////////////////////////////////
// Functions
//////////////////////////////////////////////////////////////////////////////

//////////////////////////////////////////////////////////////////////////////
TimeSet Festive.National(Text counrty)
//////////////////////////////////////////////////////////////////////////////
{
  Set s.Brazil = [[ "Brasil", "brasil", "BRASIL", "Brazil","brazil", "BRAZIL",
    "Bra", "bra", "BRA"
  ]];
  Set s.Spain = [[ "España", "españa", "ESPAÑA", "Spain","spain", "SPAIN",
    "Spa","spa", "SPA"
  ]];

  Set s.Countries = s.Brazil + s.Spain;

  TimeSet If(Not(counrty <: s.Countries),
  {
    WriteLn("[Festive.National] There are not definited national festives "+
      "of: "+country,"W");
    TimeSet W
  },
  {
    TimeSet Festive.National.Brazil(Real void)
    {
      Set festives = [[
        TimeSet DiaDoTravalho        = D(1)*M(5),
        TimeSet RevolConst           = D(9)*M(7),
        TimeSet IndepBras            = D(7)*M(9),
        TimeSet NossaSenApar         = D(12)*M(10),
        TimeSet ServidorPublico      = D(28)*M(10),
        TimeSet Finados              = D(2)*M(11),
        TimeSet ProclamacaoRepublica = D(15)*M(11),
        TimeSet Tiradentes           = D(21)*M(4)
      ]];
  
      TimeSet BinGroup("+",festives)
    };
  
    TimeSet Festive.National.Spain(Real void)
    {
      Set festives = [[
        TimeSet Constitucion   = D(6)*M(12),
        TimeSet DiaDelPilar    = D(12)*M(10),
        TimeSet DiaDelTrabajo  = D(1)*M(5),
        TimeSet Inmaculada     = D(8)*M(12),
        TimeSet TodosLosSantos = D(1)*M(11),
        TimeSet VirgenAgosto   = D(15)*M(8)
      ]];
  
      TimeSet BinGroup("+",festives)
    };

    TimeSet Case(
      counrty <: s.Brazil, Festive.National.Brazil(?),
      counrty <: s.Spain,  Festive.National.Spain(?),
      True,                TimeSet W
    )
  }) 
};
//////////////////////////////////////////////////////////////////////////////
PutDescription("It builds the timeset of national festives by country.",
Festive.National);
//////////////////////////////////////////////////////////////////////////////


//////////////////////////////////////////////////////////////////////////////
Set Build.Festives.Struct(TimeSet festives, Real referenceDay)
//////////////////////////////////////////////////////////////////////////////
{
  Real    Yini   = 1981;
  Real    Yfin   = Year(Today)+3;
  TimeSet limit  = BinGroup("+",For(Yini,Yfin,TimeSet (Real j){ Y(j) }));
  TimeSet limFes = festives*limit;

  // It gives the relative frequency coefficient between festives by day
  Real CoefNor(Real k)
  {
    TimeSet tms.k = limFes*WD(k);
    TimeSet tms.R = limFes*WD(referenceDay);

    Real _k   = SumS(CalInd(tms.k,Diario));
    Real _ref = SumS(CalInd(tms.R,Diario));

    Real If(_ref, _k/_ref,
    {
      Text WriteLn("[Build.Festives.Struct][CoefNor]: You have selected a not"
      +" valid reference day. There are not festives in WD("+
      IntText(referenceDay)+") within your sample","W");
      Real Stop
    })
  };

  // It creates a generic input for the festives
  Set festives.Nationals = [[
    Set InputDef(
      Polyn 1,
      Serie Fes.National = SubSer(CalInd(festives,Diario),DefFirst,DefLast)
    )
  ]];

  // It creates the inputs fitters for the festive inputs
  Set festives.Fitters = For(1,7,Set (Real k)
  {
    Set If(EQ(k,referenceDay), Empty,
    {
      Text name = "Fes.Fit.WD"+IntText(k);
      Serie fes.k = CalInd(festives*WD(k),Diario);
      Serie fes.r = CalInd(festives*WD(referenceDay),Diario)*CoefNor(k);
      Serie fes.f = SubSer(fes.k - fes.r,DefFirst,DefLast);

      Set InputDef(Polyn 1,Serie PutName(name,fes.f))
    })
  }) - [[ Empty ]];

  // Set of satellites
  Set Satellites = [[
    Set WD.1 = [[ Real -1 ]],
    Set WD.2 = [[ Real -1 ]],
    Set WD.3 = Empty,
    Set WD.4 = [[ 1,2,3 ]],
    Set WD.5 = [[ 1,2 ]],
    Set WD.6 = [[ Real -1 ]],
    Set WD.7 = [[ 1 ]]
  ]];

  // It creates the inputs satellites for the festive inputs
  Set festives.Satellites = BinGroup("<<",For(1,7,Set (Real j)
  {
    Set If(Not(Card(Satellites[j])), Empty,
      Set EvalSet(Satellites[j],Set (Real k)
      {
        Text    succ  = If(GT(k,0),IntText(k),"_"+IntText(SqRt(k^2)));
        Text    name  = "Fes.Sat.Succ"+succ+".Fes."+Name(Satellites[j]);
        TimeSet tms   = festives*WD(j);
        Serie   sat.k = SubSer(
          CalInd(Succ(tms,k,Diario),Diario),
          DefFirst,
          DefLast
        );

        Set InputDef(Polyn 1,Serie PutName(name,sat.k))
      })
    )
  }) - [[ Empty ]]);

  Set struct = festives.Nationals << festives.Fitters << festives.Satellites;

  Set EvalSet(struct,Real (Set idef)
  {
    Set Standard.Variables := Standard.Variables + [[ Serie idef->X ]]
  });

  Set struct
};
//////////////////////////////////////////////////////////////////////////////
PutDescription("It builds an InputDef structure for festives in three steps:
1-> A generic input for all festives.
2-> A set of fitters per week day.
3-> A set of satellites around festives.
",
Build.Festives.Struct);
//////////////////////////////////////////////////////////////////////////////


//////////////////////////////////////////////////////////////////////////////
Set Build.KeyDays.Series(TimeSet day, Text label)
//////////////////////////////////////////////////////////////////////////////
{
  Set For(1,7,Serie (Real k)
  {
    Serie input = CalInd(day*WD(k),Diario);

    Text label2 = If(label == "",
      "Holiday.key.WD"+IntText(k),
      label+".WD"+IntText(k)
    );

    Serie PutName(label2,input)
  })
};
//////////////////////////////////////////////////////////////////////////////
PutDescription("",
Build.KeyDays.Series);
//////////////////////////////////////////////////////////////////////////////


//////////////////////////////////////////////////////////////////////////////
Set Build.Holiday.KeyDays(TimeSet iniSat)
//////////////////////////////////////////////////////////////////////////////
{
  TimeSet summer       = M(6)+M(7)+M(8)+M(9);
  TimeSet Christmas    = M(11)+M(12)+M(1);
  Real check.summer    = SumS(CalInd(iniSat*summer,Diario));
  Real check.Christmas = SumS(CalInd(iniSat*Christmas,Diario));

  TimeSet tmsSat_00 = Range(iniSat, 0, 6, Diario)*WD(6);
  TimeSet tmsMon_00 = Succ(tmsSat_00, 2, Diario);

  Serie holiday.IndSem_00_WD5  = F:CalInd(tmsSat_00, Diario);
  Serie holiday.IndSem_00_WD6  =   CalInd(tmsSat_00, Diario);
  Serie holiday.IndSem_00_WD7  = B:CalInd(tmsSat_00, Diario);
  Serie holiday.IndSem_00_Rest = (1+B+B^2+B^3):CalInd(tmsMon_00, Diario);

  Set key.Days = Case(
    check.summer,
    {
      Text label = "Summer.key.";

      Set Inp.15Jun = Build.KeyDays.Series(D(15)*M(6), label+"15Jun");
      Set Inp.01Jul = Build.KeyDays.Series(D(1)*M(7),  label+"01Jul");
      Set Inp.15Jul = Build.KeyDays.Series(D(15)*M(7), label+"15Jul");
      Set Inp.01Aug = Build.KeyDays.Series(D(1)*M(8),  label+"01Aug");
      Set Inp.15Aug = Build.KeyDays.Series(D(15)*M(8), label+"15Aug");
      Set Inp.01Sep = Build.KeyDays.Series(D(1)*M(9),  label+"01Sep");
      Set Inp.15Sep = Build.KeyDays.Series(D(15)*M(9), label+"15Sep");
    
      Set Inp.15Jun << Inp.01Jul << Inp.15Jul << Inp.01Aug << Inp.15Aug <<
        Inp.01Sep << Inp.15Sep
    },
    check.Christmas,
    {
      Text label = "Christmas.key.";

      Set Inp.24Dec = Build.KeyDays.Series(D(24)*M(12), label+"24Dec");
      Set Inp.25Dec = Build.KeyDays.Series(D(25)*M(12), label+"25Dec");
      Set Inp.31Dec = Build.KeyDays.Series(D(31)*M(12), label+"31Dec");
      Set Inp.01Jan = Build.KeyDays.Series(D(1)*M(1),   label+"01Jan");
    
      Set Inp.24Dec << Inp.25Dec << Inp.31Dec << Inp.01Jan
    },
    True, Empty
  );

  Set key.Days << [[
    holiday.IndSem_00_WD5,
    holiday.IndSem_00_WD6,
    holiday.IndSem_00_WD7,
    holiday.IndSem_00_Rest
  ]]
};
//////////////////////////////////////////////////////////////////////////////
PutDescription("It builds the set of series of key days in holidays, and the
weekend days arround",
Build.Holiday.KeyDays);
//////////////////////////////////////////////////////////////////////////////


//////////////////////////////////////////////////////////////////////////////
Set Build.Weekly.HolidayStruct(TimeSet iniSat, Real numSem)
//////////////////////////////////////////////////////////////////////////////
{
  TimeSet summer       = M(6)+M(7)+M(8)+M(9);
  TimeSet Christmas    = M(11)+M(12)+M(1);
  Real check.summer    = SumS(CalInd(iniSat*summer,Diario));
  Real check.Christmas = SumS(CalInd(iniSat*Christmas,Diario));

  Text label = Case(
    check.summer,   "Summer.IndWeek.",
    check.Christmas,"Christmas.IndWeek.",
    True,           "Holidays.IndWeek."
  );

  Set sKeyDays = Build.Holiday.KeyDays(iniSat);

  Set sIndWeeks = For(1,numSem,Set (Real n)
  {
    TimeSet rng.Sat = Range(iniSat, 0, 6, Diario)*WD(6);
    TimeSet tmsSatN = Succ(rng.Sat, n, WD(6));
    TimeSet tmsMonN = Succ(Succ(rng.Sat,2,Diario),n,WD(1));

    Serie srWD5  = F:CalInd(tmsSatN, Diario);
    Serie srWD6  =   CalInd(tmsSatN, Diario);
    Serie srWD7  = B:CalInd(tmsSatN, Diario);
    Serie srRest = (1+B+B^2+B^3):CalInd(tmsMonN, Diario);

    Text nameWD5  = label+FormatReal(n, "%02.0lf")+"_WD5";
    Text nameWD6  = label+FormatReal(n, "%02.0lf")+"_WD6";
    Text nameWD7  = label+FormatReal(n, "%02.0lf")+"_WD7";
    Text nameRest = label+FormatReal(n, "%02.0lf")+"_Rest";

    Set If(LT(n, numSem),
      [[
        Serie PutName(nameWD5,srWD5),
        Serie PutName(nameWD6,srWD6),
        Serie PutName(nameWD7,srWD7),
        Serie PutName(nameRest,srRest)
      ]],
      [[
        Serie PutName(nameWD5,srWD5),
        Serie PutName(nameWD6,srWD6),
        Serie PutName(nameWD7,srWD7)
      ]]
    )
  });

  Set result = BinGroup("<<",sIndWeeks) << sKeyDays;

  Set sHolidayStruct = EvalSet(result,Serie (Serie sr)
  {
    Text name = Identify(sr);
    Serie sr2 = SubSer(sr,DefFirst,DefLast);

    Serie PutName(name,sr2)
  });

  Set struct = EvalSet(sHolidayStruct,Set (Serie s)
  {
    Set InputDef(Polyn 1, Serie s)
  });

  Set EvalSet(struct,Real (Set idef)
  {
    Set Standard.Variables := Standard.Variables + [[ Serie idef->X ]]
  });

  Set struct
};
//////////////////////////////////////////////////////////////////////////////
PutDescription("Devuelve la estructura de escalones de variables por semana,
en Sol y NotSol, definidos de manera que todos los inputs toman valor todos
los años.",
Build.Weekly.HolidayStruct);
//////////////////////////////////////////////////////////////////////////////


//////////////////////////////////////////////////////////////////////////////
// FIN
//////////////////////////////////////////////////////////////////////////////