Ticket #1198: fusion_forecast.tol

//////////////////////////////////////////////////////////////////////////////
// fusion_forecast.tol
//////////////////////////////////////////////////////////////////////////////
#Require MMS;
Date EndFore = y2015m12d01;
NameBlock JointForecasts(Set forecasts)
{
  // Set forecast = [[ fore1, fore2 ]];
  NameBlock foreUnion = (forecasts[1])::Duplicate(?);
  Text subclass = foreUnion::GetSubclass(?);
  Text version = foreUnion::GetVersion(?);
  Text name = MMS::Container::ObtainNewObjectName(
    subclass, "ForecastUnion", version
  );
  Real foreUnion::SetName(name);
  WriteLn("Fusionando dataSet");

  Set dataSets = For(2, Card(forecasts), NameBlock(Real n)
  {
    (forecasts[n])::GetModel(?)::GetDataSet(?)
  });
  Real foreUnion::GetModel(?)::GetDataSet(?)::JoinDataSets_Ignore(dataSets);
  WriteLn("Fusionando MVariables");

  Set mVariables = BinGroup("<<", For(2, Card(forecasts), Set(Real n)
  {
    (forecasts[n])::GetModel(?)::GetMVariables(?)
  }));
  Set EvalSet(mVariables, Real(NameBlock mVar)
  {
    If(
      foreUnion::GetModel(?)::FindMVariable((mVar::GetName(?))), 
      1, 
      {
        Set specification = mVar::GetSpecification(?);
        NameBlock foreUnion::GetModel(?)::CreateMVariable_Spc(specification);
        1
      }
    )
  });

  WriteLn("Fusionando subModels");

  Set subModels = BinGroup("<<", For(2, Card(forecasts), Set(Real n)
  {
    (forecasts[n])::GetModel(?)::GetSubmodels(?)
  }));

  Set EvalSet(subModels, Real(NameBlock sbm)
  {
    Set specification = sbm::GetSpecification(?);
    NameBlock foreUnion::GetModel(?)::CreateSubmodel_Spc(specification);
    1
  });
  WriteLn("Fusionando hierarchies");

  Set hierarchies = BinGroup("<<", For(2, Card(forecasts), Set(Real n)
  {
    (forecasts[n])::GetModel(?)::GetHierarchies(?)
  }));
  Set EvalSet(hierarchies, Real(NameBlock hie)
  {
    
    Set specification = hie::GetSpecification(?);
    NameBlock foreUnion::GetModel(?)::CreateHierarchy_Spc(specification);
    1
  });
  WriteLn("Fusionando mCombinations");

  Set mCombinations = BinGroup("<<", For(2, Card(forecasts), Set(Real n)
  {
    (forecasts[n])::GetModel(?)::GetMCombinations(?)
  }));
  Set EvalSet(mCombinations, Real(NameBlock mCom)
  {
    
    Set specification = mCom::GetSpecification(?);
    NameBlock foreUnion::GetModel(?)::CreateMCombination_Spc(specification);
    1
  });
  WriteLn("Fusionando mEquivalences");

  Set mEquivalences = BinGroup("<<", For(2, Card(forecasts), Set(Real n)
  {
    (forecasts[n])::GetModel(?)::GetMEquivalences(?)
  }));
  Set EvalSet(mEquivalences, Real(NameBlock mEqui)
  {
    
    Set specification = mEqui::GetSpecification(?);
    NameBlock foreUnion::GetModel(?)::CreateMEquivalence_Spc(specification);
    1
  });
  WriteLn("Fusionando parametersR");

  Set parametersR = BinGroup("<<", For(1, Card(forecasts), Set(Real n)
  {
    (forecasts[n])::GetParameters(?)
  }));
  Real foreUnion::SetParameters(parametersR);
  foreUnion
};

NameBlock JointForecastsWithExecute(Set forecasts)
{
  // Set forecasts = [[ fore1, fore2 ]];
  NameBlock object = JointForecasts(forecasts);
  Real object::Execute(?);
  object
};


//Ejemplo

Text Path = "C:/";
Text file1 = "UnionForecast.Emergencia.oza";
Text file2 = "UnionForecast.Informativas.oza";
Text file3 = "UnionForecast.Intrusion.oza";




NameBlock fore1 = MMS::Container::LoadFile(Path+file1); 
NameBlock fore2 = MMS::Container::LoadFile(Path+file2); 
NameBlock fore3 = MMS::Container::LoadFile(Path+file3);




NameBlock JointForecastsWithExecute([[ fore1, fore2, fore3 ]]);  //   ]]); //