Ticket #1134: To_Interpolacion.tol

Set Dates.(NameBlock arg)
{
  @Serie _.serie_ = [[ arg::_.serie ]], 
  @Date _.ini_  = [[ getOptArg(arg, "_.ini", First($_.serie_)) ]];
  @Date _.end_  = [[ getOptArg(arg, "_.end", Last($_.serie_))  ]];
  Real zeroIsData    = getOptArg(arg, "_.zeroIsData", 1);
  
  Set dates1 = Dates(Dating($_.serie_), $_.ini_, $_.end_);
  Set dates = SetConcat(EvalSet(dates1, Set(Date d)
  {
    Case(
      IsUnknown(SerDat($_.serie_, d)), Copy(Empty), 
      SerDat($_.serie_, d)==0 & !zeroIsData, Copy(Empty), 
      1, [[ d ]]
    )
  }))
};
Anything PutDescription("
  Saca el set de fechas de una serie _.serie donde esta definida"+NL+
  "NameBlock  arg = [["+NL+
  " Serie _.serie = serie,//Obligatorio"+NL+
  " Date _.ini = desde,  //Opcional"+NL+
  " Date _.ini = hasta   //Opcional"+NL+
  " Real _.zeroIsData = zeroIsData//Opcional"+NL+
  "]]"+NL+
  "Por defecto:"+NL+
  " Date _.ini = First(_.serie),"+NL+
  " Date _.ini = Last(_.serie) ,"+NL+
  " Real _.zeroIsData = 1."+NL+NL+
  "Real _.zeroIsData = 1 -> considerar los 0 de la serie como dato. "+NL+
  "Real _.zeroIsData = 0 -> no considerar los 0 de la serie como dato. ",
  Dates.
);


Set InterpolaSer.(NameBlock arg)
{ 
  @Serie _.serie_ = [[ arg::_.serie ]];
  Text _.tms_ =  getOptArg(arg, "_.tms", DatingName($_.serie_)); 
  Text method_    = getOptArg(arg, "_.method", "linear" ); 
  Real zeroIsData    = getOptArg(arg, "_.zeroIsData", 1); 
  Text name_ = Name($_.serie_);
  Text name = ToTolName(If(name_=="", "Ser", name_)+Name(Dating($_.serie_)));
//  @TimeSet tmsOri = [[ Dating(ser) ]];
  @Date ini = [[ First($_.serie_) ]];
  @Date fin = [[ Last($_.serie_)  ]];
  Set dates_ =  Dates.(arg);
  @Matrix x = SetOfMatrix( SetRow(EvalSet(dates_, DateToIndex)) );
  @Matrix y = SetOfMatrix(SetRow(EvalSet(dates_, Real(Date d){SerDat($_.serie_, d)})));
  Set indexTms = EvalSet(Dates(Eval("TimeSet "+_.tms_), $ini, $fin), DateToIndex);
  @Matrix xTms = SetOfMatrix( SetRow(indexTms) );
  Code c = gsl_interp(method_, $x, $y);
  @Matrix yTms = SetOfMatrix( SetRow(EvalSet(indexTms, Real(Real t) { c(0,t) })) );
  Set setSerInterpolate = MatSerSet($yTms, Eval("TimeSet "+_.tms_), $ini)
};
Anything PutDescription("
  Interpola la serie _.serie en las fechas donde no esta definida"+NL+
  "NameBlock  arg = [["+NL+
  " Serie _.serie = serie,         //Obligatorio"+NL+
  " Text _.tms = tms,              //Opcional"+NL+
  " Text _.method = met            //Opcional"+NL+
  " Real _.zeroIsData = zeroIsData //Opcional"+NL+
  "]]"+NL+
  "Por defecto:"+NL+
  " Text _.tms = DatingName(_.serie),"+NL+
  " Text _.method = linear ,"+NL+
  " Real _.zeroIsData = 1"+NL+NL+
  "Real _.zeroIsData = 1 -> considerar los 0 de la serie como dato. "+NL+
  "Real _.zeroIsData = 0 -> no considerar los 0 de la serie como dato. "+NL+
  "Los metodos que se admite son  los mismos de la funcón gsl_interp: "+NL+
  "  linear, polynomial, cspline, cspline_periodic, akima, akima_periodic",
  InterpolaSer.
);


Serie InterpolaSer(NameBlock arg)
{ 
 Serie  InterpolaSer.(arg)[1]
};

/*
Date ini1 = y2000;
Date fin1 = y2010;

Date ini2 = y2005;
Date fin2 = y2020;

Serie ori_ori = SubSer(Gaussian(10, 0.5, Mensual), ini1, fin1);

Serie ori = Copy(ori_ori);

Set datS = Dates(Mensual, ini1, fin1);

Set Omit = Unique(For(1, 12, Real(Real n)
{
  Real rand = Rand(2, Card(datS));
  Real randInteger = Floor(rand);
  PutSerDat(ori, datS[ randInteger ],  ?)

}));


Serie prev = SubSer(Gaussian(20, 0.5, Trimestral), ini2, fin2);

Serie foreMes = F:DatCh(B:prev, Mensual, FirstS);

Serie concat = Concat(
 ori,
 foreMes,
 Last(ori)
);


Serie concat_Interpola = InterpolaSer(NameBlock [[ Serie _.serie = concat, Real _.zeroIsData = 0   ]])
*/