Ticket #1033: ejemplo.tol

#Require MMS;

//////////////////////////////////////////////////////////////////////////////
// Queremos copiar detemrinados términos explicativos del submodelo 
// de una estimación al submodelo de otra

MMS::@Estimation estOri = ...;
MMS::@Estimation estDes = ...;

MMS::@Submodel submodelOri = estOri::GetModel(?)::GetSubmodel(1);
MMS::@Submodel submodelDes = estDes::GetModel(?)::GetSubmodel(1);

// Se seleccionan los términos explicativos que desean copiarse

Set expTermsOri = submodelOri::GetExpTerms(?);

Set expTermsOri_Sel = Select(expTermsOri, Real (MMS::@ExpTerm expTerm) {
  Text metric = expTerm::GetInput(?)::GetVariable(?)
    ::GetAttribute_Default("_.metrica", "");
  metric=="Pro_DamySem"
});

// Se comprueba que no existen en destino:
/*
Set expTermsDes = submodelDes::GetExpTerms(?);

Set expTermIntersection = 
  MMS::Intersection_Eq(expTermsOri_Sel, expTermsDes, MMS::SameName);

Real If(Card(expTermIntersection)>0, {
  WriteLn("Hay "<<Card(expTermIntersection)
    <<" términos que ya están en destino.", "E");
  Real Stop
});
*/

// Se extraen las variables relacionadas y sus dependencias:

Set variablesOri_Sel = MMS::Unique_Eq(SetConcat(
  EvalSet(expTermsOri_Sel, Set (MMS::@ExpTerm expTerm) {
    MMS::@Variable variable = expTerm::GetInput(?)::GetVariable(?);
    [[ PutName(variable::GetIdentifier(?), variable) ]] 
      << variable::GetDependences_ToLevel(?)
  })
), SameNameBlock);

// Se comprueba que no existen en destino:

MMS::@DataSet dataSetDes = estDes::GetModel(?)::GetDataSet(?);
/*
Set variablesDes = dataSetDes::GetVariables(?);

Set variableIntersection = 
  MMS::Intersection_Eq(variablesOri_Sel, variablesDes, MMS::SameName);

Real If(Card(variableIntersection)>0, {
  WriteLn("Hay "<<Card(variableIntersection)
    <<" variables que ya están en destino.", "E");
  Real Stop
});
*/

// Se insertan las variables en destino:

Set EvalSet(variablesOri_Sel, Anything (MMS::@Variable varOri) {
  dataSetDes::CreateVariable_Spc(varOri::GetSpecification(?))
});

// Se insertan los términos (junto a las m-variables) en destino:

MMS::@Model modelDes = estDes::GetModel(?);

Set EvalSet(expTermsOri_Sel, Anything (MMS::@ExpTerm etOri) {
  Anything modelDes::CreateMVariable_Spc(etOri::GetInput(?)
    ::GetSpecification(?));
  submodelDes::CreateExpTerm_Spc(etOri::GetSpecification(?))
});

//////////////////////////////////////////////////////////////////////////////